BUILD.gn

# Copyright 2018 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build_overrides/build.gni")
import("osp/build/config/services.gni")

# All compilable non-test targets in the repository (both executables and
# source_sets).
group("gn_all") {
  deps = [
    "cast/common:mdns",
    "cast/common/certificate",
    "cast/sender/channel",
    "osp",
    "osp/msgs",
    "platform",
    "platform:default_logger",
    "streaming/cast:receiver",
    "streaming/cast:sender",
    "third_party/abseil",
    "third_party/boringssl",
    "third_party/jsoncpp",
    "third_party/protobuf:protoc",
    "third_party/tinycbor",
    "third_party/zlib",
    "tools/cddl",
    "util",
  ]

  if (use_mdns_responder) {
    deps += [ "osp/impl/discovery/mdns:mdns_demo" ]
  }

  if (use_chromium_quic) {
    deps += [
      "third_party/chromium_quic",
      "third_party/chromium_quic:quic_demo_client",
      "third_party/chromium_quic:quic_demo_server",
    ]
  }

  if (use_chromium_quic && use_mdns_responder) {
    deps += [ "osp:osp_demo" ]
  }
}

executable("openscreen_unittests") {
  testonly = true
  deps = [
    "cast/common:unittests",
    "cast/common/certificate:unittests",
    "cast/sender/channel:unittests",
    "osp:unittests",
    "osp/impl/discovery/mdns:unittests",
    "osp/msgs:unittests",
    "platform:unittests",
    "streaming/cast:unittests",
    "third_party/abseil",
    "third_party/googletest:gtest_main",
    "util:unittests",
  ]
}

# Note: Remove this after demo is removed from the build recipe.
if (use_chromium_quic && use_mdns_responder) {
  executable("demo") {
    sources = [
      "osp/demo/osp_demo.cc",
    ]
    deps = [
      "//osp:osp_with_chromium_quic",
      "//osp/impl/discovery/mdns",
      "//platform",
      "//util",
    ]
  }
}