platform/BUILD.gn

# Copyright 2018 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build_overrides/build.gni")

source_set("platform") {
  sources = [
    "api/event_waiter.cc",
    "api/event_waiter.h",
    "api/logging.h",
    "api/logging_util.cc",
    "api/network_interface.cc",
    "api/network_interface.h",
    "api/task_runner.h",
    "api/task_runner_factory.h",
    "api/time.h",
    "api/udp_socket.h",
    "base/time.cc",
  ]

  public_deps = [
    "../osp_base",
    "../third_party/abseil",
  ]

  allow_circular_includes_from = [ "../osp_base" ]

  configs += [ "../build:allow_build_from_embedder" ]

  if (!build_with_chromium) {
    sources += [
      "base/event_loop.cc",
      "base/event_loop.h",
      "base/task_runner_factory.cc",
      "base/task_runner_impl.cc",
      "base/task_runner_impl.h",
    ]

    if (is_linux) {
      sources += [ "linux/network_interface.cc" ]
    } else if (is_mac) {
      defines = [
        # Required, to use the new IPv6 Sockets options introduced by RFC 3542.
        "__APPLE_USE_RFC_3542",
      ]

      sources += [ "mac/network_interface.cc" ]
    }

    if (is_posix) {
      sources += [
        "posix/event_waiter.cc",
        "posix/udp_socket.cc",
        "posix/udp_socket.h",
      ]
    }

    deps = [
      ":default_logger",
    ]
  }
}

source_set("default_logger") {
  sources = [
    "base/logging.cc",
  ]

  if (is_posix) {
    sources += [ "posix/log_initializer.cc" ]
  }

  configs += [ "../build:allow_build_from_embedder" ]

  deps = [
    "../osp_base",
    "../third_party/abseil",
  ]
}

source_set("platform_unittests") {
  testonly = true

  sources = [
    "api/time_unittest.cc",
  ]

  # The unit tests in base/ assume the standalone implementation is being used.
  # Exclude them if an embedder is providing the implementation.
  if (!build_with_chromium) {
    sources += [
      "base/task_runner_unittest.cc",
      "base/time_unittest.cc",
    ]
  }

  deps = [
    ":platform",
    "../third_party/googletest:gtest",
  ]

  configs += [ "../build:allow_build_from_embedder" ]
}