dev-python/clang-python: Update dependency
The library "libclang.so" which clang-python depends on is currently
installed by sys-devel/llvm.
Change package dependency from sys-devel/clang to sys-devel/llvm.
BUG=chromium:1028424
TEST=sudo emerge sys-devel/clang-python
Cq-Depend: chromium:2070651
Change-Id: I99b1ecd657de5e044f4638e68a7f19f7af149c1b
Reviewed-on: https://chromium-review.googlesource.com/c/chromiumos/overlays/chromiumos-overlay/+/2070652
Reviewed-by: Mike Frysinger <vapier@chromium.org>
Commit-Queue: Denis Nikitin <denik@chromium.org>
Tested-by: Denis Nikitin <denik@chromium.org>
diff --git a/dev-python/clang-python/clang-python-7.0.0-r2.ebuild b/dev-python/clang-python/clang-python-7.0.0-r2.ebuild
new file mode 100644
index 0000000..c1da799
--- /dev/null
+++ b/dev-python/clang-python/clang-python-7.0.0-r2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6,3_7} )
+inherit python-r1
+
+MY_P=cfe-${PV/_/}.src
+DESCRIPTION="Python bindings for sys-devel/clang"
+HOMEPAGE="https://llvm.org/"
+SRC_URI="https://releases.llvm.org/${PV/_//}/${MY_P}.tar.xz"
+
+LICENSE="UoI-NCSA"
+SLOT="0"
+KEYWORDS="*"
+IUSE="test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# The module is opening libclang.so directly, and doing some blasphemy
+# on top of it.
+RDEPEND="
+ >=sys-devel/llvm-${PV}:*
+ !sys-devel/llvm:0[clang(-),python(-)]
+ !sys-devel/clang:0[python(-)]
+ ${PYTHON_DEPS}"
+DEPEND="${RDEPEND}"
+
+S=${WORKDIR}/${MY_P}/bindings/python
+
+PATCHES=(
+ # update completion test results due to completion changes
+ # https://reviews.llvm.org/D50171
+ "${FILESDIR}"/7.0.0/0001-python-tests-Update-test_code_completion.patch
+)
+
+src_unpack() {
+ einfo "Unpacking parts of ${MY_P}.tar.xz ..."
+ tar -xJf "${DISTDIR}/${MY_P}.tar.xz" "${MY_P}/bindings/python" || die
+}
+
+python_test() {
+ "${EPYTHON}" -m unittest discover -v || die "Tests fail with ${EPYTHON}"
+}
+
+src_test() {
+ python_foreach_impl python_test
+}
+
+src_install() {
+ python_foreach_impl python_domodule clang
+}